#
# Autor: Pawe³ G³êbocki paul@softsystem.com.pl
#

function lpad(str, len){
   if (length(str)>len){
	  return str;
   }
   else {
	  ret = str;
	  j = length(str);
	  while (j<len){
		 ret = ret " ";
		 j = j+1;
	  }
	  return ret;
   }
}
	 
function storeflag(type,flname,combine,cnt,stript,addt,condt){
   i = 0;
   print "";
   print type " " flname " " combine " " cnt;
   while (i<cnt){
	  print type " " flname "   " lpad(tolower(stript[i]),9) " " lpad(tolower(addt[i]),9) " " tolower(condt[i]);
	  i = i+1;
   }
   delete stript;
   delete addt;
   delete condt;
}

BEGIN{
   cnt = 0;
   afx = "N";
   combine = "";
   flname = "";
   addt[0]="";
   stript[0]="";
   condt[0]="";
   print "SET ISO8859-2";
   print "TRY aioeznrwcysptkmd³ulj±gbhê¶æó¿fñ¼vqx";
   print "";
}
{
   if ($1 == "prefixes"){
	  afx = "PFX";
   }
   else if ($1 == "suffixes"){
	  afx = "SFX";
   }
   else{
	  if ($1 == "flag"){
		 if (length(flname)>0){
			storeflag(afx,flname,combine,cnt,stript,addt,condt);
		 }
		 cnt = 0;
		 if (length($2)>1){
			combine = "Y";
			flname = substr($2,2,1);
		 }
		 else {
			combine = "N";
			flname = $2;
		 }
	  }
	  else {
		 condt[cnt] = $1;
		 if (substr($3,1,1) == "-"){
			stript[cnt] = substr($3,2);
		 }
		 else {
			stript[cnt] = "0";
			addt[cnt] = $3;
		 }
		 if (length($4)>0){
			if (substr($4,1,1) == "-"){
			   addt[cnt] = "0";
			}
			else{
			   addt[cnt] = $4;
			}
		 }
		 cnt = cnt+1;
	  }
   }
}
END{
   if (length(flname)>0){
	  storeflag(afx,flname,combine,cnt,stript,addt,condt);
   }
}